User login

Navigation

Trebuchet II

Posted July 7th, 2007 by Tim Trim

in

Games

1000 REM Trebuchet
1010 REM Quite BASIC Game Project
1020 REM ------------------------ 
1030 CLS
1040 PRINT "The dark lords control all the castles and are terrorizing the people. You must destroy them before you are captured by the castle guard!"
1050 PRINT
1070 REM Q is the number of castles destroyed
1080 LET Q = 0
1090 REM N is the max number of attempts (0=unlimited) 
1100 LET N = 0
2000 CLC
2010 REM Pick two random elevations for the ground
2020 LET A = ROUND(RAND(25) + 0.5)
2030 LET B = ROUND(RAND(25) + 0.5)
2040 REM Draw the terrain
2050 FOR I = 0 TO 24 
2060 FOR J = 0 TO 50
2070 IF J <= A THEN PLOT I, J, "brown" ELSE PLOT I, J, "black"
2075 NEXT J
2080 NEXT I
2090 FOR I = 25 TO 49 
2095 FOR J = 0 TO 50
2100 IF J <= B THEN PLOT I, J, "brown" ELSE PLOT I, J, "black"
2105 NEXT J
2110 NEXT I
2120 IF A > B THEN LET S = -1 ELSE LET S = 1
2130 FOR I = A TO B STEP S
2140 PLOT 25, I, "brown"
2150 NEXT I
2160 REM Plot the base
2170 PLOT 10, A, "green"
2180 REM Plot the target
2190 PLOT 39, B, "red"
2200 PLOT 40, B, "red"
2210 PLOT 41, B, "red"
2220 REM Draw the castle
2230 FOR I = B+1 TO B + 3
2240 PLOT 39, I, "gray"
2250 PLOT 40, I, "gray"
2260 PLOT 41, I, "gray"
2270 PLOT 38, I+2, "gray"
2280 PLOT 42, I+1, "gray"
2290 PLOT 40, I+3, "gray"
2300 NEXT I
2303 REM Starting value for the dragon (D,E are its coordinates)
2305 LET D = 1
2306 LET E = 45
2310 PAUSE 1000
2400 LET F = 45
2410 REM W is the number of attempts
2420 LET W = 1
3000 REM Starting values for the projectile
3010 LET X = 10
3020 LET Y = A + 1
3025 LET P = 5
3030 CLT
3031 PRINT "Castles destroyed: " + Q
3032 PRINT "Attempt number " + W;
3033 IF N <>0 THEN PRINT " (max=" + N + ")" ELSE PRINT
3034 PRINT
3035 IF Q < 2 THEN PRINT "Change angle using + and -."
3036 IF Q < 2 THEN PRINT "Fire at a certain thrust by pressing 1-9."
3037 IF Q < 2 THEN PRINT
3038 PRINT "Angle: " + F
3040 PAUSE 100
3041 REM Draw the dragon!
2042 GOSUB 7000
3043 LET C = GETCHAR()
3044 IF C >= "1" AND C <= "9" THEN GOTO 3100
3045 IF C <> "+" AND C <> "-" THEN GOTO 3040
3046 IF C = "+" AND F <> 90 THEN LET F = F + 1
3047 IF C = "-" AND F <> 0 THEN LET F = F - 1
3050 GOTO 3030
3100 LET P = ROUND(C)
3130 REM Transform from speed and angle to velocity in the X and Y directions
3140 REM U is the X velocity
3150 LET U = (P+7) / 13 * COS(F/180 * PI)
3160 REM V is the Y velocity
3170 LET V = (P+7) / 13 * SIN(F/180 * PI)
3172 REM Initialize Z -- the background color
3175 LET Z = "black"
3180 REM Remove the old point by painting it the same color as the background
3190 PLOT X, Y, Z
3200 REM Update the projectile's coordinates by adding the velocity 
3210 LET X = X + U
3220 LET Y = Y + V
3230 REM Collision detection
3240 IF X < 25 AND Y < A THEN GOTO 4000
3250 IF X > 50 THEN GOTO 4000
3255 IF ABS(D+1-X) < 2 AND ABS(Y-E) < 2 THEN GOTO 4000
3260 IF X > 25 AND Y < B THEN GOTO 3500
3262 REM Save the background color in Z
3275 LET Z = COLOR(X, Y)
3270 REM Plot the projectile at its new position
3280 PLOT X, Y, "yellow"
3285 GOSUB 7000
3290 PAUSE 30
3300 REM Graviation on the projectile in the negative Y direction 
3310 LET V = V - 0.02
3320 GOTO 3190
3500 REM Check if the projectile is close enough to the target
3510 IF ABS(X - 40) > 2 THEN GOTO 4000
3515 CLT
3521 LET Q = Q + 1
3523 LET N = 2 + FLOOR(13 / Q) 
3525 IF Q = 1 THEN PRINT "You have attracted the attention of the castle guard!" 
3526 IF Q = 3 THEN PRINT "Watch out for the dragon! It can eat almost anything!"
3527 PRINT 
3528 PRINT "For your next battle, you have only " + N + " attempts before the guards find you."
3530 REM Define 40 flames by the arrays X2,Y2, and C2
3540 ARRAY X2
3550 ARRAY Y2
3560 ARRAY C2
3570 FOR I = 1 TO 40
3580 LET X2[I] = FLOOR(RAND(5)) + 38
3590 LET Y2[I] = FLOOR(RAND(5)) + B
3600 LET C2[i] = "orange"
3610 NEXT I
3620 FOR J = 1 TO 5
3630 FOR I = 1 TO 40
3640 IF Y2[I] < B+3 THEN PLOT X2[I], Y2[I], "black" ELSE PLOT X2[I], Y2[I], "black" 
3650 LET Y2[I] = Y2[I] + 1
3660 PLOT X2[I], Y2[I], C2[I]
3670 IF RAND(1) > 0.8 THEN LET C2[I] = "red"
3680 IF RAND(1) > 0.8 THEN LET C2[I] = "orange"
3690 IF RAND(1) > 0.8 THEN LET C2[I] = "yellow"
3700 IF RAND(1) > 0.3 AND Y2[I] < B+9 THEN GOTO 3750
3710 IF Y2[I] < B+3 THEN PLOT X2[I], Y2[I], "black" ELSE PLOT X2[I], Y2[I], "black" 
3720 LET X2[I] = FLOOR(RAND(5)) + 38
3730 LET Y2[I] = B
3740 LET C2[i] = "orange"
3750 PAUSE 20
3760 NEXT I
3770 NEXT J
3780 FOR I = 1 TO 40
3790 IF Y2[I]< B+3 THEN PLOT X2[I], Y2[I], "black" ELSE PLOT X2[I], Y2[I], "black"
3800 NEXT I
3780 GOTO 2000
4000 REM Miss!
4010 IF W = N THEN GOTO 5000
4020 LET W = W + 1
4030 GOTO 3000
5000 REM Game Over
5010 CLT
5020 PRINT "Sorry, that was your last try.  You have been captured by the castle guard."
5030 PRINT
5040 PRINT "You destroyed " + Q + " castles."
5050 PRINT
5060 PRINT "Click on \"Run\" to play again!" 
5070 END
7000 REM Subroutine for the dragon
7005 REM The dragons coordinates are in the D&E variables
7010 IF Q < 3 THEN RETURN
7020 IF D <= 48 THEN PLOT D+2, E, "black"
7025 LET D = D - 1
7030 IF D > 0 THEN GOTO 7100
7040 PLOT D+2, E, "black"
7050 PLOT D+1, E, "black"
7060 LET D = 50
7070 IF A > B THEN LET E = A + 8 + FLOOR(RAND(10)) ELSE LET E = B + 8 + FLOOR(RAND(10)) 
7100 PLOT D, E, "red"
7110 RETURN

Popular Projects

Trebuchet II
New version with a mini story plus the popups are gone (yay!). And watch out for the dragon! The popup is replaced by pressing +/- to change the angle and pressing 1-9 to set the force.
Pong with Scoring
A version of the Ping Pong game that keeps the score
Snake Skin
A variant of the Snake game but with a snake skin that moves.
Countries Hangman
A version of the Hangman game where the words are all countries
Tool Name Hangman
A version of the Hangman game for tools.