User login

Navigation

Submarine

Posted September 18th, 2007 by nikko

in

Games

1000 REM

2000 REM Setup background colors
2005 ARRAY Z
2010 FOR Y = 0 TO 10
2011 LET Z[Y + 40] = "cyan"
2012 LET Z[Y + 30] = "#3F3F9F"
2013 LET Z[Y + 20] = "#3F3F7F"
2014 LET Z[Y + 10] = "#3F3F5F"
2015 LET Z[Y] = "#3F3F3F"
2020 NEXT Y

2025 REM Fill background
2030 FOR Y = 0 TO 50
2040 FOR X = 0 TO 50
2050 PLOT X, Y, Z[Y]
2060 NEXT X
2070 NEXT Y

2120 REM Draw the ship
2130 PLOT 23, 41, "gray"
2140 PLOT 24, 41, "gray"
2150 PLOT 25, 41, "gray"
2160 PLOT 26, 41, "gray"
2170 PLOT 23, 42, "gray"
2180 PLOT 24, 42, "gray"
2190 PLOT 25, 42, "gray"
2210 PLOT 26, 42, "gray"
2220 PLOT 27, 42, "gray"
2230 PLOT 25, 43, "gray"

3000 REM Enemy sub positions
3010 ARRAY P
3020 ARRAY Q
3030 ARRAY V
3040 REM Number of enemy subs
3050 LET N = 0
3060 REM Initialize first Sub
3070 GOSUB 9000
3080 REM Depth charge y-coordinate and detonation depth
3090 LET D = 40
3100 LET E = -1
3110 REM Bubbles coordinates
3120 ARRAY R
3130 ARRAY S
3140 REM Number of bubbles
3150 LET B = 0

4000 REM Main game loop

4001 REM Read the keyboard
4002 IF E <> -1 THEN GOTO 4007
4003 LET K = GETCHAR()
4004 IF K < "1" OR K > "9"  THEN GOTO 4017
4005 LET E = 39 - (K * 4)
4006 LET D = 39

4007 PLOT 25, D, Z[D]
4008 LET D = D - 1
4009 PLOT 25, D, "yellow"

4010 REM Explode at set depth
4011 IF E = D THEN GOSUB 8000

4017 REM Move enemy subs
4018 IF N = 0 THEN GOTO 4160
4019 FOR I = 1 TO N
4020 LET T = Q[I] + V[I]
4030 IF T < 1 THEN LET T = 49
4040 IF T > 49 THEN LET T = 1
4050 PLOT Q[I], P[I], Z[P[I]]
4060 LET Q[I] = T
4070 PLOT Q[I], P[I], "black"
4080 REM occasionally release a bubble
4090 IF RAND(100) < 98 THEN GOTO 4150
4100 LET B = B + 1
4110 LET R[B] = Q[I]
4120 LET S[B] = P[I] + 1
4150 NEXT I

4160 REM Occasionally add a sub
4170 PAUSE 100
4180 IF RAND(100) > 99 THEN GOSUB 9000

4200 REM Move bubbles
4205 IF B = 0 THEN GOTO 4399
4210 FOR I = 1 TO B
4220 IF S[I] < 40 THEN PLOT R[I], S[I], Z[S[I]]
4240 LET S[I] = S[I] + 1
4250 LET R[I] = R[I] + ROUND((RAND(2)-1)*0.7)
4270 IF S[I] < 40 THEN PLOT R[I], S[I], "white"
4280 NEXT I

4300 REM Pop bubbles at the surface
4305 IF B = 0 THEN GOTO 4399
4308 LET J = 1
4310 FOR I = 1 TO B
4320 IF S[I] < 40  THEN GOTO 4340
4330 PLOT R[I], S[I], Z[S[I]]
4335 GOTO 4360
4340 LET S[J] = S[I]
4345 LET R[J] = R[I]
4350 LET J = J + 1
4360 NEXT I
4370 LET B = J - 1

4399 REM End bubble movement

4999 GOTO 4000

8000 REM Explosion subroutine
8005 PLOT 25, D, Z[D]
8010 FOR I = 1 TO 15
8012 LET B = B + 1
8015 LET Y = RAND(360)
8020 LET R[B] = ROUND(25 + RAND(5) * SIN(Y))
8025 LET S[B] = ROUND(E + RAND(5) * COS(Y))
8027 PLOT R[B], S[B], "red"
8030 NEXT I

8040 REM Remove all subs in range of the explosion
8050 IF N = 0 THEN GOTO 8200
8060 LET J = 1
8070 FOR I = 1 TO N
8080 LET X = Q[I] - 25
8090 LET Y = P[I] - D
8100 IF SQR(X*X + Y*Y) > 5 THEN GOTO 8130
8110 PLOT Q[I], P[I], Z[P[I]]
8120 GOTO 8170
8130 LET Q[J] = Q[I]
8140 LET P[J] = P[I]
8150 LET V[J] = V[I]
8160 LET J = J  + 1
8170 NEXT I
8180 LET N = J - 1

8200 REM Reset depth charge and finish
8210 LET E = -1
8220 LET D = 40 
8230 RETURN

9000 REM Add a sub
9010 LET N = N + 1
9020 LET V[N] = SGN(RAND(2)-1)
9030 IF V[N] = 0 THEN GOTO 9020
9040 LET Q[N] = 1
9050 LET P[N] = FLOOR(RAND(35))
9060 RETURN

Login or register to post comments

hello

On June 29th, 2008 darylroy said:

You are absolutely right !!!

Login or register to post comments

Popular Projects

Trebuchet II
New version with a mini story plus the popups are gone (yay!). And watch out for the dragon! The popup is replaced by pressing +/- to change the angle and pressing 1-9 to set the force.
Pong with Scoring
A version of the Ping Pong game that keeps the score
Snake Skin
A variant of the Snake game but with a snake skin that moves.
Countries Hangman
A version of the Hangman game where the words are all countries
Tool Name Hangman
A version of the Hangman game for tools.

more

Who's new

Active forum topics

Members

more

New forum topics

Members

more

> Quite BASIC
>

User login

Navigation

Submarine

Category

Description

hello

Popular Projects

Who's online

Who's new

Active forum topics

New forum topics

> Quite BASIC>

User login

Navigation

Submarine

Category

Description

hello

Popular Projects

Who's online

Who's new

Active forum topics

New forum topics

> Quite BASIC
>